home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Dr. Windows 3
/
dr win3.zip
/
dr win3
/
WINICONS
/
V12N11.ZIP
/
HELPRI.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-07-11
|
2KB
|
41 lines
@ECHO OFF
REM HELPRINT.BAT - Prints the output of the DOS 5.0 HELP command.
REM Put a filename on the command line to print to file.
IF '%1'=='{P}' GOTO ProcessOne
SET HelpOut=PRN
SET HelpSep=.
IF NOT '%1'=='' GOTO FileOutput
ECHO Make sure the printer is on line then
PAUSE
GOTO PrintIt
:FileOutput
SET HelpOut=%1
REM ^L in next line is Ctrl-L
SET HelpSep=
:PrintIt
ECHO Now printing condensed help information about all commmands ...
HELP > %HelpOut%
ECHO%HelpSep% >> %HelpOut%
FOR %%v IN (BREAK CALL CD CHCP CLS COPY CTTY DATE DEL DIR ECHO EXIT FOR GOTO IF) DO CALL %0 {P} %%v internal
FOR %%v IN (LH MD PATH PAUSE PROMPT RD REM REN SET SHIFT TIME TYPE VER VERIFY VOL) DO CALL %0 {P} %%v internal
FOR %%v IN (APPEND ASSIGN ATTRIB BACKUP CHKDSK COMMAND COMP DEBUG DISKCOMP) DO CALL %0 {P} %%v external
FOR %%v IN (DISKCOPY DOSKEY DOSSHELL EDIT EDLIN EMM386 ERASE EXE2BIN EXPAND FASTOPEN) DO CALL %0 {P} %%v external
FOR %%v IN (FC FDISK FIND FORMAT GRAFTABL GRAPHICS HELP JOIN KEYB LABEL LOADFIX) DO CALL %0 {P} %%v external
FOR %%v IN (MEM MIRROR MODE MORE NLSFUNC PRINT QBASIC RECOVER REPLACE RESTORE) DO CALL %0 {P} %%v external
FOR %%v IN (SETVER SHARE SORT SUBST SYS TREE UNDELETE UNFORMAT XCOPY) DO CALL %0 {P} %%v external
SET HelpOut=
SET HelpSep=
GOTO End
:ProcessOne
ECHO Now printing help information about %3 command %2
ECHO Detailed help information about %3 command %2 >> %HelpOut%
ECHO ********************************************************************************
ECHO ******************************************************************************** >> %HelpOut%
help %2 >> %HelpOut%
ECHO ********************************************************************************
ECHO ******************************************************************************** >> %HelpOut%
ECHO%HelpSep% >> %HelpOut%
:End